// $Id$

$use Arithm Box Compare Dir File StdIO System;

$func Check s.failed s.passed e.path = s.failed s.passed;

Main =
  {
    <Arg 2> : v.path = v.path;
    '.';
  } :: v.path,
  <Check 0 0 v.path> :: s.failed s.passed,
  <PrintLn "Failed: "s.failed", passed: "s.passed>,
  {
    <Gt (s.failed) (0)> = <Exit 1>;;
  };

Check s.failed s.passed e.path = {
  <IsDirectory e.path> =
    <OpenDir e.path> :: s.dir,
    s.failed s.passed $iter {
      <Check s.failed s.passed e.path <Get &DirSeparator> <ReadDir s.dir>>;
      s.failed s.passed Stop;
    } :: s.failed s.passed e.isstop,
    e.isstop : Stop =
    <CloseDir s.dir>,
    s.failed s.passed;
  e.path : e.fname '.rf',
    <Exists e.fname '.out'> =
    <Arg 1> " " e.fname <Arg 3> :: e.cmd,
    <Print e.cmd ": ">,
    <System e.cmd> :: s.e,
    <PrintLn s.e>,
    {
      s.e : 0 = s.failed <Add s.passed 1>;
//      <PrintLN "Command \""<Arg 1> " " e.fname <Arg 3>"\" exited with code "s.e>,
        <Add s.failed 1> s.passed;
    };
  s.failed s.passed;
};