// vim: set et ts=2 sw=2 :

$use Access;
$use Arithm;
$use Convert;
$use Compare;

$func QSimplify s s = t;
$func QConvert t = s s;

QAdd tX tY, <QConvert tX> :: sX1 sX2, <QConvert tY> :: sY1 sY2,
  <QSimplify <Add <Mult sX1 sY2> <Mult sX2 sY1>> <Mult sX2 sY2>>;

QSub tX tY, <QConvert tX> :: sX1 sX2, <QConvert tY> :: sY1 sY2,
  <QSimplify <Sub <Mult sX1 sY2> <Mult sX2 sY1>> <Mult sX2 sY2>>;

QMul tX tY, <QConvert tX> :: sX1 sX2, <QConvert tY> :: sY1 sY2,
  <QSimplify <Mult sX1 sY1> <Mult sX2 sY2>>;

QDiv tX tY, <QConvert tX> :: sX1 sX2, <QConvert tY> :: sY1 sY2,
  {
    <Compare (sY1) (0)> : '<', <Mult sY1 -1> <Mult sY2 -1>;
    sY1 sY2;
  } :: sY1 sY2,
  <QSimplify <Mult sX1 sY2> <Mult sX2 sY1>>;

QCompare tX tY, <QConvert tX> :: sX1 sX2, <QConvert tY> :: sY1 sY2,
  <Compare (<Mult sX1 sY2>) (<Mult sX2 sY1>)>;

QToInt tX, <DivRem <QConvert tX>> :: sQ sR, sQ;

QToString sN tX, <QConvert tX> :: s1 s2,
  <DivRem s1 s2> :: sQ sR,
  {
    <Compare (s1) (0)> :'<', { sQ : 0, '-'; /*empty*/;} :: eSing, eSing sQ <Mult sR -1>;
    sQ sR;
  } :: eOut sR,
  sN sR /*empty*/
  $iter {
     <DivRem <Mult sR 10> s2> :: sQ sR,
     <Sub sN 1> sR eOut2 sQ;
  } :: sN sR eOut2, sN : 0 = 
  'T' eOut2
  $iter {
    eOut2 : eOut3 0, 'T' eOut3;
    'F' eOut2;
  } :: sP eOut2, sP : 'F' =
  {
    eOut2 : /*empty*/, eOut;
    eOut '.' eOut2;
  } :: eOut, <ToChars eOut>; 

QFromString \{
  eIn1 '.' eIn2 =
  {eIn1 : /*empty*/, '0'; eIn1;} :: eIn1,
  <Length eIn2> 1
  $iter <Sub sN 1> <Mult sM 10> :: 
  sN sM, sN : 0 =
  \{
    eIn1 : e '-' e = <QSub <ToInt eIn1> <QDiv <ToInt eIn2> sM>>;
    <QAdd <ToInt eIn1> <QDiv <ToInt eIn2> sM>>;
  };

  eIn1 = (<ToInt eIn1> 1);
};


QSimplify s1 s2, <Gcd s1 s2> :: s3, (<Div s1 s3> <Div s2 s3>);

QConvert {
  (s1 s2) = s1 s2;
  s1 = s1 1;
};