// $Id$

$functor PStream (Stream : IStream) (Position : Stream-Position)
                 : IndexedStream;

$use Access Arithm Box;


$func PStream stream = s.pstream;

PStream stream e.name = <Box stream <Init-Position e.name>>;


*** $func Expr-Open expr (e.name) = stream;

Expr-Open expr (e.name) = <PStream <Stream.Expr-Open expr> e.name>;


*** $func File-Open  e.filename = stream;
*** $func File-Close stream     = ;

File-Open e.filename = <PStream <Stream.File-Open e.filename> e.filename>;

File-Close s.pstream, {
  <? s.pstream> : stream t.pos = <Stream.File-Close stream>;
  <Lib-Error (PStream File-Close) "Arg 1 is not a PStream"> = $fail;
};


*** $func? Getc stream = term;

Getc stream = <Gets stream 1> : term, term;


*** $func? Gets stream s.n = expr;

Gets s.pstream s.n, {
  <? s.pstream> : stream t.pos =
    <Stream.Gets stream s.n> :: expr,
    <Store s.pstream stream <Advance-Pos t.pos expr>>;
  <Lib-Error (PStream Gets) "Arg 1 is not a PStream"> = $fail;
};


*** $func Ungets stream expr = ;
/*
 * Warning!  May produce negative values for column.
 */

Ungets s.pstream expr, {
  <? s.pstream> : stream t.pos =
    <Stream.Ungets stream expr>,
    <Store s.pstream stream <Relapse-Pos t.pos expr>>;
  <Lib-Error (PStream Ungets) "Arg 1 is not a PStream"> = $fail;
};


*** $func? Get-Delim stream t.delim = expr;

Get-Delim s.pstream t.delim, {
  <? s.pstream> : stream t.pos =
    <Stream.Get-Delim stream s.n> :: expr,
    <Store s.pstream stream <Advance-Pos t.pos expr>>;
  <Lib-Error (PStream Get-Delim) "Arg 1 is not a PStream"> = $fail;
};


*** $func? Get-Line stream = expr;

Get-Line stream = <Get-Delim stream '\n'>;


*** $func Get-While stream s.pred = expr;

Get-While s.pstream s.pred, {
  <? s.pstream> : stream t.pos =
    <Stream.Get-While stream s.n> :: expr,
    <Store s.pstream stream <Advance-Pos t.pos expr>>;
  <Lib-Error (PStream Get-While) "Arg 1 is not a PStream"> = $fail;
};


*** $func? End-of-Stream? stream = ;

End-of-Stream? s.pstream, {
  <? s.pstream> : stream t.pos = <Stream.End-of-Stream? stream>;
  <Lib-Error (PStream End-of-Stream?) "Arg 1 is not a PStream"> = $fail;
};


*** $func Name   stream = e.name;
*** $func Row    stream = s.row;
*** $func Column stream = s.column;

Name s.pstream, {
  <? s.pstream> : stream t.pos = <Position.Name t.pos>;
  <Lib-Error (PStream Name) "Arg 1 is not a PStream"> = $fail;
};

Row s.pstream, {
  <? s.pstream> : stream t.pos = <Position.Row t.pos>;
  <Lib-Error (PStream Row) "Arg 1 is not a PStream"> = $fail;
};

Column s.pstream, {
  <? s.pstream> : stream t.pos = <Position.Column t.pos>;
  <Lib-Error (PStream Column) "Arg 1 is not a PStream"> = $fail;
};


*** $func Current-Pos stream = t.position;

Current-Pos s.pstream, {
  <? s.pstream> : stream t.pos = t.pos;
  <Lib-Error (PStream Current-Pos) "Arg 1 is not a PStream"> = $fail;
};