//
// Copyright (C) 1999, 2000 Refal+ Development Group
//
// Refal+ is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation; either version 2 of the License, or
// (at your option) any later version.
//
// Refal+ is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with Refal+; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
//
// $Source$
// $Revision$
// $Date$

// rfpc.rfi
$use "rfp_src"; // rfp_src.rfi
$use "rfp_err"; // rfp_err.rfi
$use "rfp_lex"; // rfp_lex.rfi
$use "rfp_parse"; // rfp_parse.rfi
$use "rfp_compile"; // rfp_compile.rfi
$use "rfp_asail_cpp"; //rfp_asail_cpp.rfi
$use "rfp_asail_java"; //rfp_asail_java.rfi
$use "rfp_asail_tpp"; //rfp_asail_tpp.rfi
$use "rfp_as2as";
$use "rfp_check";
$use "rfp_helper";
$use "rfp_format";
$use "rfp_asail_optim"; //rfp_asail_optim.rfi
$use "rfp_asail2asail";

$use Access Arithm Box Class Compare Convert CppMangle File JavaMangle
   Dos List Table StdIO;

$const RevDate = ('$Revision$') ('$Date$');
$func Version = e.version;

// information about available compiler options
$box Options;

// put information about compiler options in the &Options box
$func Init-Options = ;

// display help screen
$func Display-Help = ;

$func RFP-Parse-Args (e.files) (e.prevarg) s.index = e.files;
$func RFP-Set-Path = ;

// initialize tables
$func Get-Ready-To-Work e.Items = ;

$func CPP-Pretty-Print s.inner-call? s.channel (e.indent) e.expr = ;

// print information about compilation stages when -verbose option was
// supplied on command line
$func Verbose e.string = ;

$func Open-Channel e.name (e.ext) = s.channel s.need-close?;

$table Includes;

$func Extract-Inputs e.items = e.items;

$func? Compilation-Failed = ;


Main =
  <Init-Options>,
  <RFP-Parse-Args () () 1> :: e.files,
  <RFP-Set-Path>,
  <Store &Error-Counter 0>,
  <Store &Warning-Counter 0>,
  <? &Dir-Separator> : s.dir-separator,
//  <PrintLN e.files>,
  e.files : {
    /*empty*/ =
      {
        <In-Table? &RFP-Options HELP>;
        <PrintLN 'Refal+ compiler ' <Version>>,
          'Usage: rfpc' :: e.start,
          <Length e.start> :: s.st-len,
          <Print e.start>,
          <Box> :: s.len,
          <Store s.len s.st-len>,
          {
            <? &Options> : e (((e.next) e) t e.descr) e,
              <"<=" (<Length e.next>) (3)>,
              {
                e.descr : (e.arg) e = ' [-' e.next ' <' e.arg '>]';
                ' [-' e.next ']';
              } :: e.next,
              <Length e.next> :: s.n-len,
              <"+" <To-Int <? s.len>> s.n-len> :: s.new,
              {
                <">" (s.new) (64)> =
                  <Store s.len <"+" s.st-len s.n-len>>,
                  <PrintLN>,
                  <Print <Replicate s.st-len ' '>>;
                <Store s.len s.new>;
              },
              <Print e.next>,
              $fail;
            <PrintLN ' file ...'>;
          },
          <PrintLN>,
          <PrintLN! &StdErr 'No input files specified'>;
      };
    e01 (e.file) e02,
      {
        e.file : $r e.basename '.' e.ext = e.basename (' .' e.ext);
        e.file ();
      } :: e.in-basename (e.ext),
      {
        e01 : /*empty*/, <Lookup &RFP-Options NAME>;
        e.in-basename;
      } :: e.basename,
      {
        e.basename : $r e.dirname s.dir-separator e.filename =
          (e.dirname) e.filename;
        () e.basename;
      } :: (e.dirname) e.filename,
      {
        <Channel? e.basename> = e.in-basename;
        e.basename;
      } :: e.headname,
      <Subst (s.dir-separator) (('_')) e.headname> :: e.headname,
      <Rfp2Cpp <To-Word e.headname>> :: e.headname,
      {
        e.ext : \{ ' .rf'; ' .rfi'; } =
          <Verbose e.filename ": parsing started" >,
          <RFP-Lexer e.file> :: e.tokens,
          <Store &RFP-Token-Stack e.tokens>,
          <RFP-Parser> :: t.as,
          <Verbose e.filename ": parsing finished">,
          AS-REFAL t.as;
        e.ext : ' .asr' =
          <Channel> :: s.channel,
          <Open-File s.channel e.file R>,
          AS-REFAL <Read! s.channel>;
        e.ext : ' .ast' =
          <Channel> :: s.channel,
          <Open-File s.channel e.file R>,
          AS-TRANSFORMED <Read! s.channel>;
        e.ext : ' .asi' =
          <Channel> :: s.channel,
          <Open-File s.channel e.file R>,
          AS-AIL (AS-AIL AS-AIL <Read! s.channel> <Read! s.channel>);
        <PrintLN! &StdErr "Error: unknown extension" e.ext " in " e.file> =
          <Compilation-Failed>;
      } : s.type (s.tag t.ModuleName e.Items),
      {
        s.type : AS-AIL;
        <Get-Ready-To-Work e.Items>;
      },
      s.type e.Items $iter s.type : {
        AS-REFAL =
          {
            <In-Table? &RFP-Options AS-REFAL> =
              <Open-Channel e.basename ('.asr')> :: s.channel s.need-close?,
              <RFP-Pretty-Print s.channel () (s.tag t.ModuleName e.Items)>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; };;
          },
          \{
            <? &Error-Counter> : 0;
            <Compilation-Failed>;
          },
          {
            <In-Table? &RFP-Options NO-CHECK>;
            <Verbose "syntax check started">,
              <RFP-Check e.Items>,
              <Verbose "syntax check finished"> =
              \{
                <? &Error-Counter> : 0;
                <Compilation-Failed>;
              };
          },
          \{
            <In-Table? &RFP-Options CC>;
            <In-Table? &RFP-Options HH>;
            <In-Table? &RFP-Options JAVA>;
            <In-Table? &RFP-Options TPP>;
            <In-Table? &RFP-Options AS-AIL>;
            <In-Table? &RFP-Options AS-TRANSFORMED>;
          },
          {
            <In-Table? &RFP-Options NO-TRANSFORM> = e.Items;
            <Verbose "as-to-as transformation started">,
              <RFP-As2As-Transform e.Items> :: e.Items,
              <Verbose "as-to-as transformation finished">,
              e.Items;
          } :: e.Items,
          AS-TRANSFORMED e.Items;
        AS-TRANSFORMED =
          {
            <In-Table? &RFP-Options AS-TRANSFORMED> =
              <Open-Channel e.basename ('.ast')> :: s.channel s.need-close?,
              <RFP-Pretty-Print s.channel () (s.tag t.ModuleName e.Items)>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; };;
          },
          \{
            <In-Table? &RFP-Options CC>;
            <In-Table? &RFP-Options HH>;
            <In-Table? &RFP-Options JAVA>;
            <In-Table? &RFP-Options TPP>;
            <In-Table? &RFP-Options AS-AIL>;
          },
          <Verbose "compilation to abstract imperative language started">,
          <RFP-Compile e.Items> : (INTERFACE e.interf) (MODULE e.module),
          <Verbose "compilation to abstract imperative language finished">,
          AS-AIL
          (INTERFACE t.ModuleName e.interf) (MODULE t.ModuleName e.module);
        AS-AIL =
          {
            <In-Table? &RFP-Options AS-AIL> =
              <Open-Channel e.basename ('.asi')> :: s.channel s.need-close?,
              {
                e.Items : e t.item e,
                  <RFP-Pretty-Print s.channel () t.item>,
                  $fail;;
              },
              { s.need-close? : 1 = <Close-Channel s.channel>;; };;
          },
          \{
            <In-Table? &RFP-Options HH>,
              e.Items : (INTERFACE t.asail-mod-name v.headers) e,
              <Verbose "headers generation started">,
              <RFP-ASAIL-To-CPP t.asail-mod-name v.headers> :: e.headers,
              <Verbose "headers generation finished">,
              <Open-Channel e.basename ('.hh')> :: s.channel s.need-close?,
              <PrintLN! s.channel '#ifndef __' e.headname '_hh__'>,
              <PrintLN! s.channel '#define __' e.headname '_hh__'>,
              <PrintLN! s.channel '\n#include <rf_core.hh>'>,
              <CPP-Pretty-Print 0 s.channel () e.headers>,
              <PrintLN! s.channel '\n#endif // __' e.headname '_hh__'>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; },
              {
                <In-Table? &RFP-Options CASE-INSENSITIVE>,
                  # <Channel? e.basename>,
                  <To-Lower e.filename> :: e.lowname,
                  # \{ e.filename : e.lowname; } =
                  e.basename : e.dir e.filename,
                  e.dir e.lowname :: e.lowbase,
                  <Open-Channel e.lowbase ('.hh')> :: s.channel s.need-close?,
                  <Subst (s.dir-separator) (('_')) e.lowbase> :: e.headname,
                  <Rfp2Cpp <To-Word e.headname>> :: e.headname,
                  <PrintLN! s.channel '#ifndef __' e.headname '_hh__'>,
                  <PrintLN! s.channel '#define __' e.headname '_hh__'>,
                  <PrintLN! s.channel '\n#include <' e.basename '.hh>'>,
                  <PrintLN! s.channel '\nnamespace refal\n{'>,
                  <PrintLN! s.channel '\nnamespace ' e.lowname
                            ' = ' e.filename ';'>,
                  <PrintLN! s.channel '\n}'>,
                  <PrintLN! s.channel '\n#endif // __' e.headname '_hh__'>,
                  { s.need-close? : 1 = <Close-Channel s.channel>;; };;
              },
              $fail;
            <In-Table? &RFP-Options CC>,
              e.Items : e (MODULE t.asail-mod-name v.module),
              <Extract-Inputs v.module> :: e.module,
              {
                <In-Table? &RFP-Options NO-OPTIM> = e.module; 
                <Verbose "as-ail optimization started">,
                  <Simplify-ASAIL e.module> :: e.module,
//                  <ASAIL-Optim e.module> :: e.module,
                  <Verbose "as-ail optimization finished"> =
                  e.module;
              } :: e.module , 
              <Verbose "compilation from as-ail to c++ started">,
              <RFP-ASAIL-To-CPP t.asail-mod-name e.module> :: e.module,
              <Verbose "compilation from as-ail to c++ finished">,
              <Open-Channel e.basename ('.cc')> :: s.channel s.need-close?,
              <PrintLN! s.channel '#include <rf_core.hh>'>,
              {
                <Domain &Includes> : e (e.include) e,
                  <Lookup &Includes e.include> : \{
                    BOOT e = '<refal/'e.include'.hh>';
                    LOCAL e.path = '"'e.path e.include'.hh"';
                  } :: e.include,
                  <PrintLN! s.channel '#include 'e.include>,
                  $fail;;
              },
              <CPP-Pretty-Print 0 s.channel () e.module>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; },
              $fail;
            <In-Table? &RFP-Options TPP>,
              e.Items : e (MODULE t.asail-mod-name v.module),
              <Extract-Inputs v.module> :: e.module,
              {
                <In-Table? &RFP-Options NO-OPTIM> = e.module; 
                <Verbose "as-ail optimization started">,
                  <Simplify-ASAIL e.module> :: e.module,
//                  <ASAIL-Optim e.module> :: e.module,
                  <Verbose "as-ail optimization finished"> =
                  e.module;
              } :: e.module , 
              <Verbose "compilation from as-ail to T++ started">,
              <RFP-ASAIL-To-TPP t.asail-mod-name e.module> :: e.module,
              <Verbose "compilation from as-ail to T++ finished">,
              <Open-Channel e.basename ('.tpp')> :: s.channel s.need-close?,
              <PrintLN! s.channel '#include <rf_core.hh>'>,
              {
                <Domain &Includes> : e (e.include) e,
                  <Lookup &Includes e.include> : \{
                    BOOT e = '<refal/'e.include'.hh>';
                    LOCAL e.path = '"'e.path e.include'.hh"';
                  } :: e.include,
                  <PrintLN! s.channel '#include 'e.include>,
                  $fail;;
              },
              <CPP-Pretty-Print 0 s.channel () e.module>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; },
              $fail;                   
            <In-Table? &RFP-Options JAVA>,
              e.Items : (INTERFACE t.asail-mod-name e.headers) (MODULE t e.module),
              <Extract-Inputs e.module> :: e.module,
              {
                <In-Table? &RFP-Options NO-OPTIM> = e.module; 
                <Verbose "as-ail optimization started">,
//                  <ASAIL-Optim e.module> :: e.module,
                  <Simplify-ASAIL e.module> :: e.module,
                  {
                    e.module : e t.item e,
//                      <RFP-Pretty-Print &StdOut () t.item>,
                      $fail;;
                  },
                  <Verbose "as-ail optimization finished"> =
                  e.module;
              } :: e.module, 
              <Verbose "compilation from as-ail to java started">,
              {
                e.headers (/*e.exports*/) $iter {
                  e.headers : (s.decl t.name) e.rest =
                    e.rest (e.exports t.name);
                } :: e.headers (e.exports),
                  e.headers : /*empty*/ =
                  e.exports;
              } :: e.exports,
              <RFP-ASAIL-To-Java t.asail-mod-name (e.exports) e.module>
                :: (e.java-module-name) (e.inputs) e.module,
              <Verbose "compilation from as-ail to java finished">,
              {
                <In-Table? &RFP-Options NAME> = e.basename;
                e.dirname : v = e.dirname s.dir-separator e.java-module-name;
                e.java-module-name;
              } :: e.java-module-name,
              <Open-Channel e.java-module-name ('.java')> :: s.channel s.need-close?,
              {
                <? &RFP-Include-Path> : e (e.dir) e,
                  e.dirname : \{
                    e.dir = /*empty*/;
                    e.dir s.dir-separator e.package = e.package;
                  };
                e.dirname;
              } :: e.package,
              {
                e.package : v =
                  <PrintLN! s.channel
                  'package '<Subst (s.dir-separator) (('.')) e.package>';\n'>;;
              },
              <PrintLN! s.channel 'import org.refal.plus.*;'>,
              {
                e.inputs : e (v.java-module) e, \{
                  <Lookup &Includes v.java-module> : \{
                    BOOT e = 'org.refal.plus.library.'v.java-module;
                    LOCAL e.path,
                      <? &RFP-Include-Path> : e (e.dir) e,
                      e.path : \{
                        e.dir = /*empty*/;
                        e.dir s.dir-separator e.p = e.p;
                      } :: e.p,
                      <Subst (s.dir-separator) (('.')) e.p>
                      <Rfp2Java <To-Word v.java-module>>;
                  };
                  v.java-module;
                } :: e.java-module,
                  \{ e.java-module : e '.' e; },
                  <PrintLN! s.channel 'import 'e.java-module';'>,
                  $fail;;
              },
              <CPP-Pretty-Print 0 s.channel () e.module>,
              { s.need-close? : 1 = <Close-Channel s.channel>;; },
              $fail;
          };
      } :: s.type e.Items,
      $fail;
    e.all-files-have-gone;
  };

Init-Options = <Store &Options
  ((('I') ('ipath')) IPATH
    ("dir") "add <dir> to the list of directories to be searched" "for .rfi files")
  ((('B') ('bootpath')) BPATH
    ("dir") "add <dir> to the list of directories to be searched" "for standard library .rfi files")
  ((('ne') ('no-elaborate')) (BIND NO-ELABORATE))
  ((('nc') ('no-check')) (BIND NO-CHECK)
    "don't perform syntax check")
  ((('nt') ('no-transform')) (BIND NO-TRANSFORM)
    "don't perform AS-to-AS transformations")
  ((('c') ('check')) (BIND CHECK)
    "check only, causes no file creation in the absence"
    "of other output control options")
  ((('no') ('no-optim')) (BIND NO-OPTIM) "don't perform ASAIL-optimization")
  ((('ci') ('comp-item')) COMP-ITEM
    ("item") "compile <item> only, not the whole source" "(may be used several times)")
  ((('e') ('entry')) ENTRY
    ("func") "use function <func> as an entry to the program")
  ((('h') ('help')) HELP /*"display this help screen"*/)
  ((('v') ('verbose')) (BIND VERBOSE)
    "display information about the stages of compilation")
  ((('u')) (BIND CASE-INSENSITIVE)
    "convert all symbol-words without surrounding quotes" "to upper case")
  ((('o')) NAME
    ("name| - ") "place outputs for file1 into files <name>.* or send" "them to stdout")
  ((('cc')) (BIND CC)
    "output C++ code")
  ((('hh')) (BIND HH)
    "generate header files")
  ((('j') ('java')) (BIND JAVA)
    "output Java code")
  ((('t') ('t++')) (BIND TPP)
    "output T++ code")
  ((('asr') ('as-refal')) (BIND AS-REFAL)
    "output Refal Abstract Syntax")
  ((('ast') ('as-transformed')) (BIND AS-TRANSFORMED)
    "output Refal Abstract Syntax after AS-to-AS" "transformations")
  ((('asi') ('as-ail')) (BIND AS-AIL)
    "output Abstract Syntax of Abstract Imperative" "Language")
  ((('int')) INT ("class_name") "class to use for literal integers")
  ((('replace-module')) REPLACE-MODULE ("m1" "m2") "use module <m2> instead of <m1>")
  ((('d') ('debug')) (BIND DEBUG))
  ((('dbg')) (BIND DBG) "generate text for debugger")
  ((('trace')) TRACE
    ("fname") "trace function <fname> (may be used several times)")
  ((('traceall')) (BIND TRACEALL) "trace all functions")
>;

Display-Help =
  <Box> :: s.line,
  ' ' :: e.start1,
  29 :: s.2nd-col,
  <Replicate s.2nd-col ' '> :: e.start2,
  <PrintLN "Refal+ compiler " <Version>>,
  <PrintLN "Copyright blah-blah-blah">,
  <PrintLN>,
  <PrintLN "Usage: rfpc [options] file1 [file2 ...]">,
  <PrintLN "Options:">,
  {
    <? &Options> : e (((e.op) e.opts) t e.descr) e,
      <Store s.line e.start1 '-' e.op>,
      {
        e.opts : e (e.next) e,
          <Put s.line ', -' e.next>,
          $fail;;
      },
      {
        e.descr : (e.params) e.rest =
          {
            e.params : e s.par e,
              <Put s.line ' <' <To-Chars s.par> '>'>,
              $fail;
            e.rest;
          };
        e.descr;
      } : \{
        s.phrase e,
          <PrintLN
            <? s.line>
            <Replicate <"-" s.2nd-col <Length <? s.line>>> ' '>
            s.phrase
          >,
          $fail;
        e s s.phrase e,
          <PrintLN e.start2 s.phrase>,
          $fail;
      };;
  };

RFP-Parse-Args (e.files) (e.prevarg) s.index =
{
  <Arg s.index> : v.arg, <"+" s.index 1> :: s.index =
    <? &Dir-Separator> : s.dir-separator,
    {
      e.prevarg : v, e.prevarg :
        {
          IPATH =
            <Store &RFP-Include-Path <? &RFP-Include-Path> (v.arg)>,
            {
              $iter
                # \{
                  <? &RFP-Include-Path> : e1 (e2 s.dir-separator),
                    <Store &RFP-Include-Path e1 (e2)>;
                };
            };
          BPATH =
            <Store &RFP-Boot-Path <? &RFP-Boot-Path> (v.arg)>,
            {
              $iter
                # \{
                  <? &RFP-Boot-Path> : e1 (e2 s.dir-separator),
                    <Store &RFP-Boot-Path e1 (e2)>;
                };
            };
          COMP-ITEM =
            {
              <Lookup &RFP-Options ITEMS>;
              /*empty*/;
            } :: e.items,
            <Bind &RFP-Options (ITEMS) (e.items <Make-Name v.arg>)>;
          ENTRY =
            {
              <Lookup &RFP-Options ENTRIES>;
              /*empty*/;
            } :: e.entries,
            <Bind &RFP-Options (ENTRIES) (e.entries <Make-Name v.arg>)>;
          TRACE =
            <Bind &RFP-Trace (<Make-Name v.arg>) ()>;
          NAME =
            {
              v.arg : '-' = &StdOut;
              v.arg;
            } :: v.arg,
            <Bind &RFP-Options (NAME) (v.arg)>;
          INT =
            <Bind &RFP-Options (INT) (v.arg)>;
          REPLACE-MODULE = REPLACE-MODULE-2 v.arg;
          REPLACE-MODULE-2 e.mod1 =
            <Bind &RFP-Module-Subst (e.mod1) (v.arg)>;
        } :: e.prevarg,
        <RFP-Parse-Args (e.files) (e.prevarg) s.index>;
      v.arg : '-' e.opt =
        {
          \{
            <? &Options> : e ((e (e.opt) e) t.action e) e = t.action;
            e.opt : '-' e.o,
              <? &Options> : e ((e (e.o) e) t.action e) e = t.action;
          } : {
            (BIND s.option) = <Bind &RFP-Options (s.option) ()>;
            HELP = <Bind &RFP-Options (HELP) ()>, <Display-Help>;
            s.other = s.other;
          } :: e.prevarg,
            <RFP-Parse-Args (e.files) (e.prevarg) s.index>;
          <PrintLN! &StdErr "Unknown option \"-" e.opt "\"">,
            <RFP-Parse-Args (e.files) () s.index>;
        };
      <RFP-Parse-Args (e.files (v.arg)) () s.index>;
    };
  e.prevarg : v =
    <PrintLN! &StdErr "Last option requires parameter">,
    <Exit 1>;
  {
    \{
      <In-Table? &RFP-Options CC>;
      <In-Table? &RFP-Options HH>;
      <In-Table? &RFP-Options TPP>;
      <In-Table? &RFP-Options JAVA>;
      <In-Table? &RFP-Options AS-REFAL>;
      <In-Table? &RFP-Options AS-TRANSFORMED>;
      <In-Table? &RFP-Options AS-AIL>;
      <In-Table? &RFP-Options CHECK>;
    };
    <Bind &RFP-Options (CC) ()> <Bind &RFP-Options (HH) ()>;
  },
    e.files;
};

RFP-Set-Path =
  <Store &RFP-Boot-Path <? &RFP-Boot-Path> &RFP-Default-Include-Path>,
  <Store &RFP-Include-Path <? &RFP-Include-Path> <? &RFP-Boot-Path>>;

Get-Ready-To-Work e.Items =
  <RFP-Clear-Table &Includes>,
  <RFP-Clear-Table &Fun>,
  <RFP-Clear-Table &Fun?>,
  <RFP-Clear-Table &Const>,
  <RFP-Clear-Table &Object>,
  {
    e.Items : e t.Item e, t.Item : \{
      (s.Linkage s.ItemType t.Pragma t.ItemName e.ItemBody),
        s.ItemType : {
          FUNC = 
            <Left 0 2 e.ItemBody> : (e.in) (e.out),
            &Fun (<Format-Exp e.in>) (<Format-Exp e.out>);
          TFUNC = 
            <Left 0 2 e.ItemBody> : (e.in) (e.out),
            &Fun (<Format-Exp e.in>) (<Format-Exp e.out>);
          FUNC? =
            <Left 0 2 e.ItemBody> : (e.in) (e.out),
            &Fun? (<Format-Exp e.in>) (<Format-Exp e.out>);
          CONST = &Const e.ItemBody;
          s = &Object e.ItemBody;
        } :: s.tab e.ItemDef,
        <Bind s.tab (t.ItemName) (s.Linkage s.ItemType t.Pragma e.ItemDef)>;
      (EXTERN t.Pragma t.FName) =
        <Bind &Fun? (t.FName) (IMPORT FUNC? t.Pragma ((EVAR)) ((EVAR)))>;
    },
      $fail;
    {
      <In-Table? &RFP-Options DBG> =
        <Bind &Fun? ((Debug Stop?)) (IMPORT FUNC? (PRAGMA) ((EVAR)) ())>,
        <Bind &Fun  ((Debug Debug)) (IMPORT FUNC  (PRAGMA) ((EVAR)) ())>;;
    };
  };

RFP-Pretty-Print s.channel (e.indent) e.expr = e.expr :
  {
    e0 (e1) e2 =
      <Write! s.channel e0>,
      { e.indent : v = <PrintLN! s.channel>;; },
      <Print! s.channel e.indent '('>,
      <RFP-Pretty-Print s.channel (e.indent '  ') e1>,
      {
        e1 : e (e) e =
          <PrintLN! s.channel>,
          <Print! s.channel e.indent ')'>;
        <Print! s.channel ')'>;
      },
      {
        e2 : (e) e = ;
        e2 : , e.indent : v = ;
        <PrintLN! s.channel>, <Print! s.channel e.indent>;
      },
      <RFP-Pretty-Print s.channel (e.indent) e2>;
    v1 =
      <Write! s.channel v1>;
    =;
  };

$const Tab = '  ';

CPP-Pretty-Print s.inner-call? s.channel (e.indent) e.expr, e.expr : {
  e0 (e1) e2 =
    { s.inner-call? : 0 = <PrintLN! s.channel>;; },
    {
      e0 : /*empty*/, {
        e1 : LABEL e.label =
          e.indent : e.ind &Tab,
          <PrintLN! s.channel e.ind e.label>;
        e1 : /*empty*/ =
          <PrintLN! s.channel>;
        <CPP-Pretty-Print 1 s.channel (e.indent) e1>;
      };
      <PrintLN! s.channel e.indent e0>,
        <CPP-Pretty-Print 1 s.channel (e.indent &Tab) (e1)>;
    },
    <CPP-Pretty-Print s.inner-call? s.channel (e.indent) e2>;
  v1 = <PrintLN! s.channel e.indent v1>;
  /*empty*/ = /*empty*/;
};

Verbose e.string, {
  <In-Table? &RFP-Options VERBOSE> =
    <PrintLN <Time> ": " e.string>;;
};

Open-Channel {
  symbol (e), <Channel? symbol> = symbol 0;
  e.name (e.ext) =
    <Channel> :: s.channel,
    {
      <Open-File s.channel e.name e.ext W> =
        s.channel 1; // When we need to close channel ???
      <PrintLN! &StdErr "Error: cannot open file " e.name e.ext " for writing">,
        <Exit 1>, $fail;
    };
};

Extract-Inputs {
  (INPUT (e.mod-name) e.file-name) e.items, <? &Dir-Separator> : s.dir-separator, {
    e.file-name : $r e.path s.dir-separator e.name, {
      <? &RFP-Boot-Path> : e (e.path e.rest) e \?
        {
          e.rest : e1 s2 e3 \?
            {
              s2 : s.dir-separator \! $fail;
              \!\! $fail;
            };
          <Bind &Includes (e.mod-name) (BOOT e.path s.dir-separator)>;
        };
      {
        e.path : '.' = /*empty*/;
        e.path : '.' s.dir-separator e.rest, {
          e.rest : e1 s2 e3, # \{ s2 : s.dir-separator; } =
            s2 e3 s.dir-separator;
          /*empty*/;
        };
        e.path s.dir-separator;
      } :: e.path,
        <Bind &Includes (e.mod-name) (LOCAL e.path)>;
    };
    <Bind &Includes (e.mod-name) (LOCAL)>;
  },
    <Extract-Inputs e.items>;
  e.items =
    {
      <In-Table? &RFP-Options DBG> = <Bind &Includes (Debug) (BOOT)>;;
    },
    e.items;
};

Compilation-Failed = <Exit 1>;

Version = {
  &RevDate : (e ' ' v.rev ' ' e) (e ' ' v.date ' ' e) = '2.0-beta-' v.rev ', ' v.date;
  '2.0-unknown-beta';
};