// $Source$
// $Revision$
// $Date$

$use Apply Arithm Box Class Compare Convert CppMangle List StdIO Table;
$use "rfpc";
$use "rfp_helper";

$box Int;

$box Module-Name;

$box Current-Namespace;

$box Current-Func;

$box Current-Trace;

$box Entry;

$box Entry-Name;

$box Const-Exprs;

$table Externs;

$func ASAIL-To-CPP e.body = e.cpp-code;

$func Namespace-Control e.qualifiers = e.namespace-control;

$func Expr-To-CPP (e.ASAIL-Expr-init) e.ASAIL-Expr-rest = e.ASAIL-Expr;

$func Expr-Ref-To-CPP e.ASAIL-Expr-Ref = e.CPP-Expr-Ref;

$func Expr-Int-To-CPP e.ASAIL-Expr-Int = e.CPP-Expr-Int;

$func Step-To-CPP e.step-operators = e.cpp-step-operators;

$func Const-Expr-To-CPP e.ASAIL-const-expr = e.CPP-const-expr;

$func Args-To-CPP (e.prefix) s.Arg-Res-Tag e.ASAIL-Args = e.CPP-Args;

$func Symbol-To-CPP s.RFP-Symbol = e.CPP-String;

$func Name-To-CPP t.name = e.CPP-Name;

$func Cond-To-CPP e.cond = e.CPP-Cond;

$func Infix-To-CPP s.func-for-converting-args-to-cpp s.op e.args = e.cpp-expr;

$func Op-Arg-To-CPP s.op = s.func-for-converting-args-to-cpp;

$func Trace-Enter e.name (e.args) = e.trace;
$func Trace-Exit  e.name (e.ress) = e.trace;
$func Trace-Fail  e.name          = e.trace;

$func Extract-Qualifiers t.name = (e.qualifiers) e.name;


RFP-ASAIL-To-CPP (e.ModuleName) e.asail =
  {
    <Store &Int <Lookup &RFP-Options INT>>;
    <Store &Int Integer>;
  },
  <Store &Module-Name e.ModuleName>,
  <Store &Current-Namespace /*empty*/>,
  {
    <Store &Entry <Lookup &RFP-Options ENTRIES>>;
    <Store &Entry (e.ModuleName Main)>;
  },
  <Store &Entry-Name /*empty*/>,
  <Store &Const-Exprs /*empty*/>,
  <RFP-Clear-Table &Externs>,
  {
    <ASAIL-To-CPP e.asail> : v.cpp,
      {
        <? &Current-Namespace> : v = ('}');;  // close last namespace
      } :: e.close-namespace,
      <Store &Current-Namespace /*empty*/>,
      {
        <? &Entry-Name> : v.name = ('rfrt::Entry rf_entry (' v.name ');');;
      } :: e.entry,
      {
        <? &Const-Exprs> : v.c-exprs =
          (/*e.init-consts*/) <? &Const-Exprs> $iter {
            e.c-exprs : (e.cpp-name (e.value)) e.rest =
              (e.init-consts (e.cpp-name ' = ' e.value ';')) e.rest;
          } :: (e.init-consts) e.c-exprs,
          e.c-exprs : /*empty*/ =
          <Namespace-Control <? &Module-Name>>
          ('static void init_ ()\n{' (e.init-consts) '}')
          ('static AtStart init_registrator_ (&init_);')
          ('}');;
      } :: e.init,
      ('namespace refal\n{')
      ('using namespace rfrt;')
      v.cpp e.close-namespace e.init e.entry
      ('}');;
  };

ASAIL-To-CPP e.asail, {
  e.asail : t.item e.rest, t.item : {
    (s.tag t.name (e.args) (e.ress) e.body),
      s.tag : \{
        FUNC  = ('void') /*empty*/;
        FUNC? = ('boolean') ('return true;');
      } :: (e.return-type) e.return =
      <Store &Current-Func t.name>,
      { <? &Entry> : e t.name e = <Store &Entry-Name <Rfp2Cpp t.name>>;; },
      {
        \{
          <In-Table? &RFP-Options TRACEALL>;
          <In-Table? &RFP-Trace t.name>;
        } =
          <Intersperse ('.') <Concat t.name>> :: e.name,
          <Store &Current-Trace e.name (e.ress)>,
          (<Trace-Enter e.name (e.args)>) (<Trace-Exit e.name (e.ress)>);
        <Store &Current-Trace /*empty*/>,
          () ();
      } :: (e.trace-enter) (e.trace-exit),
      <Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('RF_FUNC (' <Rfp2Cpp e.name> ', '
            <Args-To-CPP ('RF_ARG ') Vars e.args> ', '
            <Args-To-CPP ('RF_RES ') Vars e.ress> ')'
        (e.trace-enter <ASAIL-To-CPP e.body> e.trace-exit)
       'RF_END');
    (TRACE t.name) =
      <Bind &RFP-Trace (t.name) ()>;
    (IF (e.cond) e.body) =
      ('if (' <Cond-To-CPP e.cond> ')')
      ('{' (<ASAIL-To-CPP e.body>) '}');
    (FOR (e.cont-label) (e.break-label) (e.cond) (e.step) e.body) =
      {
        e.cont-label : t =
          ('{'
            ('{' (<ASAIL-To-CPP e.body>) '}')
            (LABEL <Rfp2Cpp (LABEL e.cont-label)> ': {}')
          '}');
        ('{' (<ASAIL-To-CPP e.body>) '}');
      } :: e.body,
      {
        e.break-label : t = (LABEL <Rfp2Cpp (LABEL e.break-label)> ': {}');;
      } :: e.break,
      ('for ( ; ' <Cond-To-CPP e.cond> '; ' <Step-To-CPP e.step> ')') e.body e.break;
    (LABEL (e.label) e.body) =
//      {
//        e.label : /*empty*/ =
//          ('{' (<ASAIL-To-CPP e.body>) '}' );
        ('{' (<ASAIL-To-CPP e.body>) '}')
        (LABEL <Rfp2Cpp (LABEL e.label)> ': {}');
//      };
    (TRY e.body) =
      ('RF_TRAP') ('{' (<ASAIL-To-CPP e.body>) '}');
    (CATCH-ERROR e.body) =
      ('RF_WITH') ('{' (('RF_CLEANUP;') <ASAIL-To-CPP e.body>) '}');
    RETURN =
      {
        <? &Current-Trace> : e.name (e.ress) =
          <Trace-Exit e.name (e.ress)>;
        /*empty*/;
      } :: e.trace-exit,
      e.trace-exit ('return true;');
    RETFAIL =
      {
        <? &Current-Trace> : e.name (e.ress) =
          <Trace-Fail e.name>;
        /*empty*/;
      } :: e.trace-exit,
      e.trace-exit ('RF_RETFAIL;');
    FATAL =
//      <? &Current-Func> : (e.name),
      ('RF_FUNC_ERROR (unexpected_fail);');
    (LSPLIT e.expr (e.min) t.var1 t.var2) =
      ('RF_lsplit (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.min> ', '
      <Rfp2Cpp t.var1> ', ' <Rfp2Cpp t.var2> ');');
    (RSPLIT e.expr (e.min) t.var1 t.var2) =
      ('RF_rsplit (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.min> ', '
      <Rfp2Cpp t.var1> ', ' <Rfp2Cpp t.var2 > ');');
    (ASSIGN t.var e.expr) =
      (<Rfp2Cpp t.var> ' = ' <Expr-To-CPP () e.expr> ';');
    (DECL s.type t.var) =
      ('Expr ' <Rfp2Cpp t.var> ';');
    (INT  t.var e.expr) =
      ('uintptr_t ' <Rfp2Cpp t.var> ' = ' <Expr-Int-To-CPP e.expr> ';');
    (EXPR t.var e.expr) =
      ('Expr ' <Rfp2Cpp t.var> ' (' <Expr-Ref-To-CPP e.expr> ');');
    (DEREF t.var e.expr (e.pos)) =
      ('Expr ' <Rfp2Cpp t.var> ' (' <Expr-Ref-To-CPP e.expr> ', '
      <Expr-Int-To-CPP e.pos> ');');
    (SUBEXPR t.var e.expr (e.pos) (e.len)) =
      ('Expr ' <Rfp2Cpp t.var> ' ('
      <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.pos> ', ' 
      <Expr-Int-To-CPP e.len> ');');
    (DROP t.var) =
      (<Rfp2Cpp t.var> '.drop ();');
    (CONTINUE t.label) =
      ('goto ' <Rfp2Cpp (LABEL t.label)> ';');
    (BREAK t.label) =
      ('goto ' <Rfp2Cpp (LABEL t.label)> ';');
    (ERROR e.expr) =
      ('RF_ERROR (' <Expr-Ref-To-CPP e.expr> ');');
    (CONSTEXPR s.linkage t.name (e.comment) e.expr) =
      { s.linkage : LOCAL = 'static ';; } :: e.linkage,
      {
        t.name : (STATIC e) = (<? &Module-Name>) t.name;
        <Extract-Qualifiers t.name>;
      } :: (e.qualifiers) e.name,
      <Rfp2Cpp e.name> :: e.cpp-name,
      <Put &Const-Exprs (e.cpp-name (<Const-Expr-To-CPP e.expr>))>,
      <Namespace-Control e.qualifiers>
      (e.linkage 'Expr ' e.cpp-name ';');
    (OBJ s.linkage s.tag t.name) =
      { s.linkage : LOCAL = 'static ';; } :: e.linkage,
      <To-Chars s.tag> : s1 e2,
      <Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Rfp2Cpp e.name> :: e.cpp-name,
      {
        s.tag : BOX =
          <Put &Const-Exprs (e.cpp-name
            ('Expr::create_sym< rftype::NamedObject<rftype::BoxContents> >('
              'L"'e.name'")'))>;
//        s.tag : VECTOR =
//          <Put &Const-Exprs (e.cpp-name
//            ('Expr::create_sym< rftype::NamedObject<rftype::Vector> >('
//              'L"'e.name'")'))>;
        <Put &Const-Exprs (e.cpp-name
          ('new rftype::StaticObject<rftype::' s1 <To-Lower e2> '>(L"'e.name'")'))>;
      },
      <Namespace-Control e.qualifiers>
      (e.linkage 'Expr ' e.cpp-name ';');
    (DECL-OBJ t.name) =
      <Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('extern Expr ' <Rfp2Cpp e.name> ';');
    (DECL-FUNC t.name) =
      <Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('RF_DECL (' <Rfp2Cpp e.name> ');');
    (EXTERN t.name) =
      <Bind &Externs (t.name) ()>,
      <Extract-Qualifiers t.name> :: (e.qualifiers) e.name,
      <Namespace-Control e.qualifiers>
      ('RF_DECL (' <Rfp2Cpp e.name> ');');
    /*
     * s.call can be CALL or TAILCALL or TAILCALL?
     */
    (s.call t.name (e.exprs) (e.ress)) =
      {
        # \{ s.call : CALL; }, <? &Current-Trace> : e.full-name (e.ress) =
          ('if (RF_CALL (' <Name-To-CPP t.name> ', '
            <Args-To-CPP () Exprs e.exprs> ', ' <Args-To-CPP () Vars e.ress> '))')
          ('{' (<Trace-Exit e.full-name (e.ress)> ('return true;')) '}')
          ('else RF_RETFAIL;');
        {
          s.call : TAILCALL? = TAILCALL;
          s.call;
        } :: s.call,
          ('RF_' s.call ' (' <Name-To-CPP t.name> ', '
            <Args-To-CPP () Exprs e.exprs> ', ' <Args-To-CPP () Vars e.ress> ');');
      };
  } :: e.cpp-item,
    e.cpp-item <ASAIL-To-CPP e.rest>;
  /*empty*/;
};

/*
 * Determine type of e.expr - int or Refal.
 */
Expr-To-CPP  (e.init) e.expr-all, e.expr-all : {
  /*empty*/ = <Expr-Ref-To-CPP e.init>;
//  s.ObjectSymbol e.rest, {
//    <Int? s.ObjectSymbol> = <Expr-Int-To-CPP e.init e.expr-all>;
//    <Expr-Ref-To-CPP e.expr-all>;
//  };   
  (PAREN e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (EXPR e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (DEREF e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (SUBEXPR e.expr) e.rest = <Expr-Ref-To-CPP e.init e.expr-all>;
  (LENGTH e.expr) e.rest = <Expr-Int-To-CPP e.init e.expr-all> ;
  (MAX e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;         
  (MIN e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;
  (INFIX s.op e.args) e.rest = <Expr-Int-To-CPP e.init e.expr-all>;
  (s.var-tag (e.QualifiedName)) e.rest =
    <Expr-To-CPP (e.init (s.var-tag (e.QualifiedName))) e.rest>;
};


$func Term-Ref-To-CPP e = e;

Expr-Ref-To-CPP {
  /*empty*/ = 'empty';
  term = <Term-Ref-To-CPP term>;
  expr = '(' <Infix-To-CPP &Term-Ref-To-CPP "+" <Paren expr>> ')';
};

Term-Ref-To-CPP {
  (PAREN e.expr) =
    <Expr-Ref-To-CPP e.expr> ' ()';
  (EXPR e.expr) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ')';
  (DEREF e.expr (e.pos)) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ', ' <Expr-Int-To-CPP e.pos> ')';
  (SUBEXPR e.expr (e.pos) (e.len)) =
    'Expr (' <Expr-Ref-To-CPP e.expr> ', '
        <Expr-Int-To-CPP e.pos>   ', ' <Expr-Int-To-CPP e.len> ')';
  (REF t.name) = <Name-To-CPP t.name>;
  ERROR-EXPR = 'err';
  (STATIC t.name) =
    <? &Current-Namespace> :: e.namespace,
    {
      <? &Module-Name> : e.namespace = /*empty*/;
      <? &Module-Name>'::';
    } :: e.prefix,
    e.prefix <Rfp2Cpp (STATIC t.name)>;
  (s.var-tag e.ns t.name) = <Rfp2Cpp (s.var-tag e.ns t.name)>;
};

Expr-Int-To-CPP {
  /*empty*/ = /*empty*/;
  s.ObjectSymbol = 
    {
      <Int? s.ObjectSymbol> = s.ObjectSymbol;
      $error ("Illegal type int-symbol: " s.ObjectSymbol);
    };
  (LENGTH e.expr) =
    <Expr-Ref-To-CPP e.expr> '.get_len ()';
  (MAX e.args) =
    'pxx_max (' <Args-To-CPP () Ints e.args> ')';
  (MIN e.args) =
    'pxx_min (' <Args-To-CPP () Ints e.args> ')';
  (INFIX s.op e.args) =
    '(' <Infix-To-CPP &Expr-Int-To-CPP s.op e.args> ')';
  (REF t.name) = <Name-To-CPP t.name>;
  (s.var-tag t.name) = <Rfp2Cpp (s.var-tag t.name)>;
  expr = '(' <Infix-To-CPP &Expr-Int-To-CPP "+" <Paren expr>> ')';
};

Cond-To-CPP {
  /*empty*/ = /*empty*/;
  (CALL t.name (e.exprs) (e.ress)) =
    'RF_CALL (' <Name-To-CPP t.name> ', '
          <Args-To-CPP () Exprs e.exprs> ', '
          <Args-To-CPP () Vars e.ress>   ')';
  (SYMBOL? e.expr (e.pos)) =
    <Expr-Ref-To-CPP e.expr> '.symbol_at (' <Expr-Int-To-CPP e.pos> ')';
  (FLAT-SUBEXPR? e.expr (e.pos) (e.len)) =
    <Expr-Ref-To-CPP e.expr> '.flat_at ('
      <Expr-Int-To-CPP e.pos> ', ' <Expr-Int-To-CPP e.len> ')';
  (CHECK-ITER e.expr) =
    'RF_iter(' <Expr-Ref-To-CPP e.expr> ')';
  (EQ e.expr1 (e.expr2) (e.pos)) =
    <Expr-Ref-To-CPP e.expr1> '.eq ('
      <Expr-Ref-To-CPP e.expr2> ', ' <Expr-Int-To-CPP e.pos> ')'; 
  (TERM-EQ e.expr1 (e.expr2) (e.pos)) =
    <Expr-Ref-To-CPP e.expr1> '.term_eq ('
      <Expr-Ref-To-CPP e.expr2> ', ' <Expr-Int-To-CPP e.pos> ')'; 
  (NOT e.cond) =
    '!' <Cond-To-CPP e.cond>;
  (INFIX s.op e.args) =
    '(' <Infix-To-CPP <Op-Arg-To-CPP s.op> s.op e.args> ')';
  expr = '(' <Infix-To-CPP &Cond-To-CPP "&&" <Paren expr>> ')';
}; 

Infix-To-CPP s.arg2cpp s.op e.args, {
  e.args : (e.arg) e.rest =
    <Apply s.arg2cpp e.arg> :: e.arg,
    <Infix-To-CPP s.arg2cpp s.op e.rest> :: e.rest,
    {
      e.arg : v, e.rest : v = e.arg ' ' s.op ' ' e.rest;
      e.arg e.rest;
    };;
};

Op-Arg-To-CPP s.op, {
  s.op : \{ "&&"; "||"; } =
    &Cond-To-CPP;
  s.op : \{ "<"; ">"; "<="; ">="; "=="; "!="; "+"; "-"; "%"; "*"; "/"; } =
    &Expr-Int-To-CPP;
};
 
Step-To-CPP {
  /*empty*/ = /*empty*/;
  (INC-ITER e.expr) = 'RF_iter(' <Expr-Ref-To-CPP e.expr> ')++';
  (DEC-ITER e.expr) = 'RF_iter(' <Expr-Ref-To-CPP e.expr> ')--';
};



$func Const-Expr-Aux e.expr = e.cpp-expr;

Const-Expr-To-CPP {
  /*empty*/ = 'empty';
  (SUBEXPR t.name s.pos s.len) = 'Expr (' <Rfp2Cpp t.name> ', ' s.pos ', ' s.len ')';
                  //FIXME: надо проверять, что s.pos и s.len
                  //       не превышают допустимых величин.
                  //       Задавать эти величины опциями.
  e.expr =
    <Const-Expr-Aux () e.expr> : {
      ' + ' e.cpp-expr = e.cpp-expr;
      e.cpp-expr = e.cpp-expr;
    };
};

Const-Expr-Aux (e.accum) e.expr, {
  e.expr : s.sym e.rest, <Char? s.sym> =
    <Const-Expr-Aux (e.accum <Symbol-To-CPP s.sym>) e.rest>;
  e.accum : v =
    {
      <Chars-To-Bytes e.accum> : e s.c e,
        <">" (s.c) (127)> =
        ' + Char::create_expr ("' e.accum '")' <Const-Expr-Aux () e.expr>;
      //' + Expr::create_seq<Char> (L"' e.accum '")' <Const-Expr-Aux () e.expr>;
      ' + Char::create_expr (L"' e.accum '")' <Const-Expr-Aux () e.expr>;
    };
  e.expr : t.item e.rest, t.item : {
    (PAREN e.paren-expr) =
      ' + (' <Const-Expr-To-CPP e.paren-expr> ') ()';
    (REF t.name) =
      ' + ' <Name-To-CPP t.name>;
//      ' + Expr::create<ObjectRef>(' <Name-To-CPP t.name> ')';
    (STATIC e) =
      ' + ' <Rfp2Cpp t.item>;
    (s.FUNC t.name), s.FUNC : \{ FUNC; FUNC?; } =
      ' + Expr::create_sym<Func> (' <Name-To-CPP t.name> ')';
    s.sym, {
      <Int? s.sym> = 
        ' + Expr::create<' <? &Int> '>("' s.sym '")';
      <Word? s.sym> =
        ' + Expr::create<Word>("' <Symbol-To-CPP s.sym> '")';
    };
  } :: e.cpp-item =
    e.cpp-item <Const-Expr-Aux () e.rest>;
  = /*empty*/;
};

Symbol-To-CPP s.ObjectSymbol, {
  <To-Chars s.ObjectSymbol> () $iter {
    e.symbol : s.char e.rest, s.char : {
      '\\' = '\\\\';
      '\n' = '\\n';
      '\t' = '\\t';
//        '\v' = '\\v';
//        '\b' = '\\b';
      '\r' = '\\r';
//        '\f' = '\\f';
      '\"' = '\\"';
//      '\'' = '\\\'';
      s = s.char;
    } :: e.cpp-char,
    e.rest (e.cpp-symbol e.cpp-char);
  } :: e.symbol (e.cpp-symbol),
    e.symbol : /*empty*/ =
    e.cpp-symbol;
};



Args-To-CPP {
  (v.prefix) Vars /*empty*/  = 'RF_VOID';
  (        ) Vars /*empty*/  = '/*void*/';
  (        ) Vars (e.arg)    = <Rfp2Cpp (e.arg)>;
  (e.prefix) Exprs /*empty*/ = '/*void*/';
  (e.prefix) Exprs (e.arg)   = <Expr-Ref-To-CPP e.arg>;
  (e.prefix) s.tag e.args =
    e.args () $iter {
      e.args : (e.arg) e.rest =
        {
          e.rest : v = ', ';
          /*empty*/;
        } :: e.comma,
        s.tag : {
          Vars = e.rest (e.cpp-args <Rfp2Cpp (e.arg)> e.comma);
          Exprs = e.rest (e.cpp-args <Expr-Ref-To-CPP e.arg> e.comma);
          Ints = e.rest (e.cpp-args <Expr-Int-To-CPP e.arg> e.comma);
        };
    } :: e.args (e.cpp-args),
    e.args : /*empty*/,
    (e.prefix) s.tag : {
      t   Exprs = '(' e.cpp-args ')';
      ( ) Vars  = '(' e.cpp-args ')';
      (v) Vars  = '(' e.prefix e.cpp-args ';;)';
      e         = e.prefix e.cpp-args;
    };
};

Name-To-CPP t.obj-name =
  <RFP-Extract-Qualifiers t.obj-name> :: (e.qualifiers) e.name,
  <? &Current-Namespace> :: e.namespace,
  {
    e.qualifiers : e.namespace e.cont = <Rfp2Cpp e.cont e.name>;
    <Rfp2Cpp (e.qualifiers e.name)>;
  };

Namespace-Control e.qualifiers =
  {
    e.qualifiers : /*empty*/ = <? &Module-Name>;
    e.qualifiers : () = /*empty*/;
    e.qualifiers;
  } :: e.qualifiers,
  {
    <? &Current-Namespace> : e.qualifiers;
    {
      <? &Current-Namespace> : v = ('}');;
    } :: e.close-namespace,
      <Store &Current-Namespace e.qualifiers>,
      {
        e.qualifiers : v = ('namespace ' <Rfp2Cpp e.qualifiers> '\n{');;
      } :: e.open-namespace,
      e.close-namespace e.open-namespace;
  };

Trace-Enter e.name (e.args) =
  e.args 1 () $iter {
    e.args : t.arg e.rest =
      {
        \{ e.rest : v; <">" (s.n) (1)>; } = 'printf("%2d: ", 's.n');';
        'printf("  : ");';
      } :: e.num,
      e.rest <"+" s.n 1>
      (e.pr-args ('printf ("           argument "); 'e.num' ('<Rfp2Cpp t.arg>').writeln(stdout);'));
  } :: e.args s.n (e.pr-args),
  e.args : /*empty*/ =
  ('printf ("+ %5u: enter >>> 'e.name' <<<\\n", rfrt::stack->get_depth());') e.pr-args;

Trace-Exit e.name (e.args) =
  e.args 1 () $iter {
    e.args : t.arg e.rest =
      {
        \{ e.rest : v; <">" (s.n) (1)>; } = 'printf("%2d: ", 's.n');';
        'printf("  : ");';
      } :: e.num,
      e.rest <"+" s.n 1>
      (e.pr-args
       ('printf ("           result   "); 'e.num' ('<Rfp2Cpp t.arg>').to_Expr().writeln(stdout);'));
  } :: e.args s.n (e.pr-args),
  e.args : /*empty*/ =
  ('printf ("- %5u: exit  >>> 'e.name' <<<\\n", rfrt::stack->get_depth());') e.pr-args;

Trace-Fail e.name =
  ('printf ("- %5u: fail  >>> 'e.name' <<<\\n", rfrt::stack->get_depth());');

Extract-Qualifiers t.name, {
  <In-Table? &Externs t.name> =
    t.name : (e.n),
    (()) e.n;
  <RFP-Extract-Qualifiers t.name>;
};