// $Id$

$use Apply Arithm Box Class Convert Dir File Java List StdIO Table ;
$use "rfpc" "rfp_helper" ;

$import "java.io.BufferedReader";
$import "org.refal.plus.comp.CompilerEnvironment";
$import "org.refal.plus.library.RefalLibrary";

$func? Arg_GetInterfaceReader t.fileId = e.reader;
$func? Arg_GetImplementationReader t.fileId = e.reader (e.qname);
$func? Arg_GetInterfaceReaderForModule e.name = e.reader (e.qname);
$func? Arg_GetInterfaceReaderForClass e.name = e.reader (e.qname);
$func? Env_GetInterfaceReader t.fileId = e.reader;
$func? Env_GetImplementationReader t.fileId = e.reader (e.qname);
$func? Env_GetInterfaceReaderForModule e.name = e.reader (e.qname);
$func? Env_GetInterfaceReaderForClass e.name = e.reader (e.qname);

$box Env Package ;

RFP_Src_Get_Line e.source =
  e.source : s.srctype s.getline_func (e.name) (e.src),
  <Apply s.getline_func e.src>;

RFP_Src_Close s.srctype s.getline_func (e.name) (e.src) =
  s.srctype :
  {
    FILE = e.src : s.channel, {
      <IsChannel s.channel> = <CloseChannel s.channel>;
      <BRclose s.channel>;
    };
    STDIN = ;
  };

RFP_Src_GetInterfaceReader t.fileId =
  {
    <Get &Env> : s = <Env_GetInterfaceReader t.fileId>;
    = <Arg_GetInterfaceReader t.fileId>;
  };

RFP_Src_GetImplementationReader t.fileId =
  {
    <Get &Env> : s = <Env_GetImplementationReader t.fileId>;
    = <Arg_GetImplementationReader t.fileId>;
  };

RFP_Src_GetInterfaceReaderForModule e.name =
  {
    <Get &Env> : s = <Env_GetInterfaceReaderForModule e.name>;
    = <Arg_GetInterfaceReaderForModule e.name>;
  };

RFP_Src_GetInterfaceReaderForClass e.name =
  {
    <Get &Env> : s = <Env_GetInterfaceReaderForClass e.name>;
    = <Arg_GetInterfaceReaderForClass e.name>;
  };


$func? Try_Open e.filename = e.source;
$func? Get_Line_From_File e.source = e.line ;

RFP_Src_InitFromArgs e.files =
  {
    <Store &Package <Make_Name <Lookup &RFP_Options PACKAGE>>>;
    <Store &Package>;
  };

Arg_GetInterfaceReader $r (e.file '.' e) =
  <Try_Open e.file '.rfi'>;

Arg_GetImplementationReader (e.file) =
  <Get &DirSeparator> : s.dir_separator,
  e.file : {
    $r e s.dir_separator e.name '.' e = e.name;
    $r e.name '.' e = e.name;
  } :: e.name,
  <Try_Open e.file> (<Get &Package> <ToWord e.name>);

Arg_GetInterfaceReaderForModule e.name =
  <Get &DirSeparator> : s.dir_separator,
  <Intersperse (s.dir_separator) e.name> :: e.fname,
  \{
    <Get &RFP_Include_Path> : e (e.dirname) e,
      <Try_Open e.dirname e.fname '.rfi'> (e.name);
    <Get &RFP_Boot_Path> : e (e.dirname) e,
      <Try_Open e.dirname e.fname '.rfi'> ("refal" "plus" e.name);
  };

Arg_GetInterfaceReaderForClass e.name =
  <Get &DirSeparator> : s.dir_separator,
  "org" "refal" "plus" "wrappers" e.name :: e.name,
  <Intersperse (s.dir_separator) e.name> :: e.fname,
  <Get &RFP_Include_Path> : e (e.dirname) e,
  <Try_Open e.dirname e.fname '.rfi'> (e.name);

Try_Open e.filename =
  {
    <IsRFP_Debug>, <PrintLn "Trying to open \'" e.filename "\'">;;
  },
  {
    <RFP_Src_IsCaseInsensitive> \?
      <Get &DirSeparator> : s.dir_separator,
      {
        e.filename : $r e.dirname s.dir_separator e.fname = (e.dirname) e.fname;
        ('.') e.filename;
      } :: (e.dirname) e.fname,
      <ToUpper <ToChars e.fname>> :: e.fname,
      <OpenDir e.dirname> :: s.dir,
      $iter,
      {
        <ReadDir s.dir>;
        \! $fail;
      } :: e.filename,
      <ToUpper e.filename> : e.fname,
      <Channel> :: s.chl,
      <OpenFile s.chl e.dirname s.dir_separator e.filename "r">,
      e.dirname s.dir_separator e.filename s.chl;
    = <Channel> :: s.chl,
      <OpenFile s.chl e.filename "r">,
      e.filename s.chl;
  } :: e.filename s.chl,
  {
    <IsRFP_Debug>, <PrintLn "\'" e.filename "\' successfully opened">;;
  },
  FILE &Get_Line_From_File (e.filename) (s.chl);

Get_Line_From_File s.channel =
  <ReadLineCh s.channel>;


$func? Get_Line_From_Reader s.reader = e.line;

RFP_Src_InitFromEnv s.env = 
  <Bind &RFP_Options ("IDENT-COMPATIBILITY") ()>,
  <Store &Env s.env>;

Env_GetInterfaceReader t = 
  <Get &Env> : s.env,
  <GetInterfReader s.env <GetModuleName s.env>> :: s.reader,
  {
    <Null> : s.reader = $fail;
    FILE &Get_Line_From_Reader (<GetModuleName s.env>) (<BufferedReader s.reader>);
  };

Env_GetImplementationReader t =
  <Get &Env> : s.env,
  <GetImplemReader s.env> : s.reader,
  {
    <Null> : s.reader = $fail;
    FILE &Get_Line_From_Reader (<GetModuleName s.env>) (<BufferedReader s.reader>) (<GetModuleName s.env>);
  };

Env_GetInterfaceReaderForModule e.name =
  <Get &Env> : s.env,
  <ToWord <Intersperse ('/') e.name>> :: s.qname,
  <GetInterfReader s.env s.qname> :: s.reader,
  {
    <Null> : s.reader =
      <RLgetInterfReader s.qname> :: s.reader,
      {
        <Null> : s.reader = $fail;
        s.reader ("refal" "plus" e.name);
      };
    s.reader (e.name);
  } :: s.reader (e.name),
  FILE &Get_Line_From_Reader (e.name) (<BufferedReader s.reader>) (e.name);

Env_GetInterfaceReaderForClass e.name =
  <Get &Env> : s.env,
  "org" "refal" "plus" "wrappers" e.name :: e.name,
  <ToWord <Intersperse ('/') e.name>> :: s.qname,
  <GetInterfReader s.env s.qname> :: s.reader,
  {
    <Null> : s.reader = $fail;
    FILE &Get_Line_From_Reader (e.name) (<BufferedReader s.reader>) (e.name);
  };

Get_Line_From_Reader s.reader =
  <BRreadLine s.reader> :: s.string,
  {
    <Null> : s.string = $fail;
    <ToChars s.string>;
  };


RFP_Src_IsCaseInsensitive = <IsInTable &RFP_Options "CASE-INSENSITIVE">;

RFP_Src_WordFirstSymbol = {
  <IsInTable &RFP_Options "IDENT-COMPATIBILITY"> = '_';
  '?!';
};

RFP_Src_WordSymbol = {
  <IsInTable &RFP_Options "IDENT-COMPATIBILITY"> = '_.';
  '?!-';
};

RFP_Src_VarSymbol = {
  <IsInTable &RFP_Options "IDENT-COMPATIBILITY"> = '_';
  '?!-';
};


RFP_Src_InitPosition = 0 1;

RFP_Src_NextRow s.row s.col =
  <Arithm.Add s.row 1> 1;

RFP_Src_NextColumn s.row s.col =
  s.row <Arithm.Add s.col 1>;

RFP_Src_PositionToChars s.row s.col = <ToChars s.row '-' s.col>;