//
// File: GRSCN.RF
//
// Project: GR
//

//
// e.Tokens = { e.Token }.
// e.Token = Key s.Key | Name s.Name | Char s.Char.
// s.Key  = s.Word.
// s.Name = s.Word.
//

$use Box;
$use Class;
$use Convert;
$use Dos;
$use StdIO;

$func  ScanToken       s.Chl e.Line = s.TokenKey s.TokenInfo (e.Line1);
$func  ScanIdRest     (e.IdChars)  e.Chars = s.TokenKey s.Word (e.Rest);
$func  ScanComment     s.Chl e.Line = s.TokenKey s.TokenInfo (e.Line1);
$func? IsComment         s.Char e.Line = e.Rest;
$func? IsBlank           s.Char = ;
$func? IsOneCharToken  s.Char = ;
$func? IsCompoundToken  s.Char e.Line = s.Word e.Rest;

$box ScanChl ScanLine;

InitScanner  s.Chl =
  <Store &ScanChl s.Chl>,
  <Store &ScanLine >;

TermScanner  =
  <Store &ScanChl   >,
  <Store &ScanLine  >;

ReadToken  =
  <Get &ScanChl> : s.Chl,
  <Get &ScanLine> :: e.Line,
  <ScanToken s.Chl e.Line> :: s.TokenKey s.TokenInfo (e.Line),
  <Store &ScanLine e.Line>,
    = s.TokenKey s.TokenInfo;

ScanToken  s.Chl e.Line =
  e.Line :
  {
  =
    {
    <ReadLineCh s.Chl> :: e.Line
      = <ScanToken s.Chl e.Line>;
      = Key Eof ();
    };
  s.Char e.Rest =
    {
    <IsComment s.Char e.Rest> :: e.Rest
      = <ScanComment s.Chl e.Rest>;
    <IsBlank s.Char>
      = <ScanToken s.Chl e.Rest>;
    <IsLetter s.Char>
      = <ScanIdRest (s.Char) e.Rest>;
    <IsOneCharToken s.Char>
      = Key <ToWord s.Char> (e.Rest);
    <IsCompoundToken s.Char e.Rest> :: s.Word e.Rest
      = Key s.Word (e.Rest);
      = Char s.Char (e.Rest);
    };
  };

ScanComment s.Chl e.Line =
  {
  e.Line : e '*/' e.Rest
    = <ScanToken s.Chl e.Rest>;
    = {
      <ReadLineCh s.Chl> :: e.Line
        = <ScanComment s.Chl e.Line>;
        = <PrintLnCh &StdErr "EOF in a comment">,
          <Exit 1>,
          Key Eof ();
      };
  };

ScanIdRest  (e.IdChars) e.Rest =
  {
  e.Rest : s.Char e.Rest1,
           \{ <IsLetter s.Char>; <IsDigit  s.Char>; s.Char : '_'; }
    = <ScanIdRest (e.IdChars s.Char) e.Rest1>;
    = Name <ToWord e.IdChars> (e.Rest);
  };

IsBlank  s.Char =
  ' \n\t' : e s.Char e;

IsOneCharToken  s.Char =
  ':|;' : e s.Char e;

IsCompoundToken
  \{
  '%%'     e.Rest = "%%" e.Rest;
  '%token' e.Rest = "%token" e.Rest;
  };

IsComment
  '/*' e.Rest = e.Rest;