//
// File GRPRN.RF
//
// Project: GR
//

$use StdIO;

$func PrintSetLoop e.TkList = ;
$func PrintSetRest e.TkList = ;

PrintGrammar (e.Tokens) (e.Rules) =
  <PrintLnCh &WriteFileCh "%token\n  ">,
  <PrintSet e.Tokens>,
  <PrintLnCh &WriteFileCh "\n%%\n">,
  <PrintRules e.Rules>;

PrintSet e.TkList =
  <PrintCh &WriteFileCh "(">
  <PrintSetLoop e.TkList>
  <PrintCh &WriteFileCh ")">;

PrintSetLoop
  {
  s1 s2 s3 s4 s5 v.Rest =
    <PrintCh &WriteFileCh s1><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s2><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s3><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s4><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s5><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh "\n  ">,
    = <PrintSetLoop v.Rest>;
  s1 s2 s3 s4 s5 =
    <PrintCh &WriteFileCh s1><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s2><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s3><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s4><PrintCh &WriteFileCh " | ">
    <PrintCh &WriteFileCh s5>;
  e.Rest =
    <PrintSetRest e.Rest>;
  };

PrintSetRest
  {
  s1 v.Rest =
    <PrintCh &WriteFileCh s1><PrintCh &WriteFileCh " | "><PrintSetRest v.Rest>;
  s1 =
    <PrintCh &WriteFileCh s1>;
  = ;
  };

PrintRules
  {
  $l e (sN e.Rules) e,
    <PrintLnCh &WriteFileCh sN>,
    \{
    e.Rules : $l eL (e.Rhs) eR,
      { eL : = ":"; = "|";} :: s.Prefix,
      <PrintCh &WriteFileCh "        "><PrintCh &WriteFileCh s.Prefix><PrintCh &WriteFileCh "   ">
      <PrintRhs e.Rhs>
      <PrintLnCh &WriteFileCh>, $fail;
    <PrintCh &WriteFileCh "        ;\n\n">,
      $fail;
    },
    $fail;
  e;
  };

PrintRhs
  {
  = <PrintCh &WriteFileCh "/* empty */">;
  $l e (s.Tag s.Sym) e,
    <PrintCh &WriteFileCh s.Sym>,
    <PrintCh &WriteFileCh " "> $fail;
  e = ;
  };

PrintAnnSym (e.Nullable) s.Sym =
  {
  e.Nullable : e s.Sym e
    = <PrintCh &WriteFileCh "#">;
    = ;
  },
  <PrintCh &WriteFileCh s.Sym>;

PrintAnnRhs (e.Nullable) (e.Rhs) =
  e.Rhs :
  {
  = <PrintCh &WriteFileCh "/* empty */">;
  $l e (s.Tag s.Sym) e,
    <PrintAnnSym (e.Nullable) s.Sym>,
    <PrintCh &WriteFileCh " "> $fail;
  e = ;
  };

PrintEnv
  {
  $l e (s.N (eV)) e,
    <PrintLnCh &WriteFileCh><PrintCh &WriteFileCh s.N><PrintCh &WriteFileCh " ->\n  ">,
    <PrintSet eV> $fail;
  e = <PrintLnCh &WriteFileCh>;
  };