* vim: et:sw=4:ts=4

IntCall {
    (e.program) ((FUNC s.fname e.sentences) e.func_defs) s.name e.args, s.fname : {
        s.name = <IntFunc (e.program) (e.sentences) e.args>;
        s.other = <IntCall (e.program) (e.func_defs) s.name e.args>;
    };
}

IntFunc {
    (e.program) ((SENTENCE s.name (e.patterns) e.exp) e.sentences) e.args, <MkSubst (e.patterns) e.args> : {
        e.1 Fail = <IntFunc (e.program) (e.sentences) e.args>;
        e.subst = <IntExp (e.program) (e.subst) e.exp>;
    };
}

MkSubst {
    ((e.pat) e.patterns) (e.arg) e.args, <MkSubst1 (e.pat) e.arg> : {
        e.1 Fail = Fail;
        e.subst = e.subst <MkSubst (e.patterns) e.args>;
    };
    () /*empty*/ = /*empty*/
}

MkSubst1 {
    ((VAR s.tag s.name)) (s.tag e.data) = ((VAR s.tag s.name) (s.tag e.data));
    (e.pattern) (s.tag e.data) = <MkSubst2 (e.pattern) e.data>;
}

MkSubst2 {
    ((VAR s.tag s.name) e.pattern) (s.tag e.data) e.arg = ((VAR s.tag s.name) (s.tag e.data)) <MkSubst2 (e.pattern) e.arg>;
    (s.1 e.pattern) s.1 e.arg = <MkSubst2 (e.pattern) e.arg>;
    () /*empty*/ = ;
    (e.pattern) e.arg = Fail;
};

IntExp {
    (e.program) (e.subst) (UNDEFINED), <Print "Reached UNDEFINED"> : () = ;
    (e.program) (e.subst) (EXP s.tag e.data) = (s.tag <IntExp2 (e.program) (e.subst) e.data>);
    (e.program) (e.subst) s.sym = s.sym;
    (e.program) (e.subst) (VAR s.tag s.name) = <Subst (e.subst) (VAR s.tag s.name)>;
    (e.program) (e.subst) (CALL s.name e.args) = <IntCall (e.program) (e.program) s.name <IntArgs (e.program) (e.subst) e.args>>;
    (e.program) (e.subst) (PAREN e.exp) = <IntExp (e.program) (e.subst) e.exp>;
    (e.program) (e.subst) (IF (e.cond) (e.true) (e.false)), <IntExp (e.program) (e.subst) e.cond> : {
        (Bool 'True') = <IntExp (e.program) (e.subst) e.true>;
        (Bool 'False') = <IntExp (e.program) (e.subst) e.true>;
    };
    (e.program) (e.subst) (LET (e.assigns) e.exp) = <IntLet (e.program) (e.subst) (e.assigns) e.exp>;
}

IntExp2 {
    (e.program) (e.subst) t.term e.exp = <IntExp (e.program) (e.subst) t.term> <IntExp2 (e.program) (e.subst) e.exp>;
    (e.program) (e.subst) /*empty*/ = /*empty*/;
}

IntArgs {
    (e.program) (e.subst) (e.exp) e.args = (<IntExp (e.program) (e.subst) e.exp>) <IntArgs (e.program) (e.subst) e.args>;
    (e.program) (e.subst) /*empty*/ = /*empty*/;
}

IntLet {
    (e.program) (e.subst) (((VAR s.tag s.name) e.exp1) e.assigns) e.exp =
        <IntLet (e.program) (e.subst ((VAR s.tag s.name) <IntExp (e.program) (e.subst) e.exp1>)) (e.assigns) e.exp>;
    (e.program) (e.subst) () e.exp = <IntExp (e.program) (e.subst) e.exp>;
}

Subst {
    (((VAR s.tag s.name) t.value) e.subst) (VAR s.tag s.name) = t.value;
    (t.1 e.subst) (VAR s.tag s.name) = <Subst (e.subst) (VAR s.tag s.name)>;
}

$ENTRY Go {
    = <Prout
        <IntExp ((FUNC "isBit"
                    (SENTENCE "isBit" (('0')) (EXP Bool 'True'))
                    (SENTENCE "isBit" (('1')) (EXP Bool 'True'))
                    (SENTENCE "isBit" (((VAR Bin "b"))) (EXP Bool 'False'))))
                ()
                (CALL "isBit" ((EXP Bin (EXP Bin '1') '0')))>>;
}